Por favor, activa JavaScript y desactiva tu adblock para este sitio

El Javatar

Blog dedicado a la Programación en Java, C, PHP, Phyton, HTML, SQL y Mucho Más

sábado, 10 de mayo de 2014

Diagrama de Flujo y Pseudocódigo para Hallar el Máximo Común Divisor

Diagrama de Flujo y Pseudocódigo para Hallar el Máximo Común Divisor
Hace varios días expliqué un algoritmo para hallar el Máximo Común Divisor entre dos números enteros; más específicamente el algoritmo de Euclides (leer aquí el artículo). Explicamos este algoritmo ya que es muy sencillo aplicarlo en prácticamente cualquier lenguaje de programación, y a fin de cuentas eso es lo que nos interesa.

Sin embargo, hoy no lo implementaremos en un lenguaje de programación, al menos no en uno forma de alto nivel. En esta entrada veremos primero cómo se diseñaría el diagrama de flujo de este algoritmo, y posteriormente veremos su implementación en Pseudocódigo.

Así que primero veamos cómo se realizaría el diagrama de flujo:

Diagrama de Flujo para Hallar el Maximo Comun Divisor

Como verás, en el diseño del diagrama de flujo podemos notar una diferencia en cuanto al código que realizamos en Java, puesto que como aquí no contamos con funciones para hallar el mayor o el menor entre dos números, debemos hacerlo "manualmente" a través de una condición.

Bien, ahora miremos como sería entonces la implementación en Pseudocódigo:

Proceso
    // Definimos las variables que usaremos
    Definir num1,num2,a,b,res Como Entero
    // Pedimos al usuario que ingrese los datos
    Escribir 'Ingrese el primer numero'
    Leer num1
    Escribir 'Ingrese el segundo numero'
    Leer num2
    // Seleccionamos el mayor y el menor para
    // asignarlos a las variables "a" y "b"
    Si num1>num2 Entonces
        a<-num1
        b<-num2
    Sino
        a<-num2
        b<-num1
    FinSi
    // Hacemos el ciclo encargado de
    // realizar las iteraciones
    Mientras b!=0 Hacer
        res<-b
        b<-a MOD b
        a<-res
    FinMientras
    // Mostramos el resultado en pantalla
    Escribir 'El M.C.D. entre ',num1,' y ',num2,' es: ',res
FinProceso

Bueno, ahora solo nos queda probar si tanto el diagrama de flujo como el pseudocódigo funcionan. En este caso, como yo realicé los dos usando Pseint, la ejecución será la misma. Como lo hemos venido haciendo, haremos la prueba con los datos de entrada 12 y 16, por lo tanto el resultado debe ser 4:

Salida en Pantalla - Como Hallar el Máximo Común Divisor en Pseudocodigo

No hay comentarios.:

Publicar un comentario